;:ifpeek(36864)+peek(36865)+peek(40950)<>320thenload"profi-ass",8,8
;:open15,8,15,"s:code":close15
;:poke56,144:clr
;:open8,8,8,"code,p,w
;:sys36864
	*= 32768
	;.opt o8
scrn	=648
bank	=56576
cint	=65409
vic	=53248
sptr	=51192
spr	=59392
irqold	=$ea31
irqvkt	=788
joy	=56320
wech	=57856
konf	=1
bild	=$d1
calcx	=$e9f0
stack	=$c001
ptr	=2
irqspd	=56325
bsout	=$ffd2
tmp	=4
uhr	=162
color	=646
farbram	=$ea24
farb	=$f3
diff	=55296-50176
sc1	=50210
	fa1 =sc1+diff
sc2	=50416
	fa2 =sc2+diff
sc3	=50176
	fa3 =sc3+diff
sc4	=50195
	fa4 =sc4+diff
spa	=211
cursor	=58732
crs1	=204
crs2	=205
crs3	=207
get	=65508
zei	=214
tmp2	=247
tmp3	=249
endscr	=50176+1000
key	=198
irqoff	=$ea81
zei1	=97
irql	=$dc0d
gn	=$ba
sa	=$b9
setnam	=$ffbd
load	=$ffd5
status	=144
hiadr	=51200
aktiv	=820
clrx	=59903
axout	=$bdcd
space	=$ab3f
tspd	=250
jobs	=704
possi	=53228
ziff	=57728
hipname	=53208
setpar	=$ffba
open	=$ffc0
close	=$ffc3
save	=$ffd8
clall	=$ffe7
flo	=8
hiende	=hiadr+1600
ioflag	=157
secber	=50436
sysctl	=0
levelmem	=$a000
levelend	=$bf40
richt	=jobs+8
pauses	=$eeb3
anfscr	=50396+diff
downline	=56096
	jmp loslauf
kug	.byt $3c,$7e,-1,-1,-1,-1,$7e,$3c
	.byt $3c,$7e,-1,$e7,$c3,$c3,$c3,$c3
	.byt $c3,$c3,$c3,$c3,$e7,-1,$7e,$3c
	.byt $3f,127,240,224,224,240,127,$3f
	.byt $fc,$fe,15,7,7,15,$fe,$fc
pic	.byte "\x93\x08\x01\x05\x11\x17\x17\x1e\xb3\x98\xa4\xa5\x9d\x9d\x91\x97\xa2\xa3\x11\x17\x17\x17\x98\xbe\x05\x12 \x92S\x98"
	.byte "\xbe\x9d\x9d\x9d\x9d\x91~\x05\x12  \x92\x98\xdf\x05\x9d\x9d\x9d\x91"
	.byte "YZ\x9d\x9d\x91\x12  \x92\x9d\x9d\x91\xdb\xdc\x1d\x01\x04\x11\x17\x17\x17\x17\x17\x17\x03"
wiese	.byte "\x1e\xb3\xb4\xb5\x1a\x91\x9dU\x11\x03"
stamm	.byte "@ \xa9\xaa\xab\xac\xab\xac 1990   designed &  "
	.byte "  programmed   by n.heusler "
	.byte "play the game!"
hiscr	.byte "s:"
hiname	.byte "oil.highs"
stscr	.byte "s:"
stname	.byte "oil.stage ?"
title	.byte "\x93\x08\x11\x9aN\x01&QOR\x01\x0f \x9e\xc0\xc0\xc0 \xc0 \xc0\x01\x10} \x9aRR\x01\x0f \x9e\xc0 \xc0 \xc0 \xc0"
	.byte "\x01\x10} \x9aRR\x01\x0f \x9e\xc0 \xc0 \xc0 \xc0\x01\x10} \x9aRR\x01\x0f \x9e\xc0 \xc0 \xc0 \xc0\x01\x10} \x9aRR\x01\x0f"
	.byte " \x9e\xc0\xc0\xc0 \xc0 \xc0\xc0\xc0\x01\x0e \x9aRR\x01& RR  \x96 \xc0\xc0 \xc0 \xc0  \xc0  \xc0   \xc0"
	.byte "   \xc0\xc0\xc0 \xc0\xc0   \xc0\xc0 \xc0\xc0\xc0 \x9aRR  \x96\xc0   \xc0 \xc0 \xc0 \xc0 \xc0   \xc0"
	.byte "   \xc0   \xc0 \xc0 \xc0   \xc0   \x9aRR  \x96\xc0   \xc0\xc0\xc0 \xc0\xc0\xc0 \xc0   \xc0"
	.byte "   \xc0\xc0\xc0 \xc0 \xc0 \xc0 \xc0 \xc0\xc0\xc0 \x9aRR  \x96\xc0   \xc0 \xc0 \xc0 \xc0 \xc0   \xc0"
	.byte "   \xc0   \xc0 \xc0 \xc0 \xc0 \xc0   \x9aRR  \x96 \xc0\xc0 \xc0 \xc0 \xc0 \xc0 \xc0\xc0\xc0 \xc0"
	.byte "\xc0\xc0 \xc0\xc0\xc0 \xc0 \xc0  \xc0\xc0 \xc0\xc0\xc0 \x9aRM\x01&QP\x01\x0a\x91\x01\x05\x1d\x99\xa9\xaa\xab\xac\xab\xac"
	.byt 13
	.byte "\x05\x91\x91\x01\x1d\x1d\xdb\xdc\x11\x9d\x9d\x12  \x92\x9d\x9d\x11YZ\x9d\x9d\x9d\x11~\x12  \x92\xdf\x9d\x9d\x9d\x9d\x11"
	.byte "\xbe\x12 \x92S\xbe\x9d\x9d\x11\xb2\x11\x9d\xb2\x11\x9d\xb2\x11\x9d\x9d\xbd\xaf\x11\x11\x03"
paut	.byte "\x10}\x01\x15\x13\x05"
step1	.byte "\x13\x01\x0f\x11\x01\x06 \x9cwritten by  \x81nikolaus heusler"
	.byt 13
	.byte "\x11\x01\x04 zwengauerweg 18, 8000 mTnchen 71"
	.byt 13
	.byte "\x11\x01\x0c \x9ca \x81\xa9\xaa\xab\xac\xab\xac\x9c-program"
	.byt 13
	.byte "\x11\x01\x05 \x9c@ \x8102/1990\x9c nig software service"
	.byt 13
	.byte "\x11\x01\x05 all rights reserved\x01\x05 vers.\x814\x03"
step2	.byte "\x13\x01\x0f\x11\x01\x0c \x1f- \xb7\xba\xbb \x96\xb7\xb8\xb9\x1f \xbc\xb8\xb8 -\x03"
tunt	.byte "\x13\x01\x08\x11\x01\x0c  \x1eN\x01\x0cQO\x01\x0e\x9d\x11R \x9eget ready!\x1e R"
	.byte "\x11\x01\x0e\x9dM\x01\x0cQP"
	.byt 13
	.byte "\x11\x11\x01\x11 \x9alevel:\x81\x11\x11\x03"
posix	.byt 13
	.byte "\x01\x10} \x03"
gomt	.byte "\x13\x1c\x01\x0e\x11\x1d\x01\x0c\x1d \x01\x0bX "
	.byt 13
	.byte "\x1d\x01\x0c\x1d\xa0\x01\x0b W"
	.byt 13
	.byte "\x1d\x01\x0c\x1d\xa0 \x1fgame over\x1c W"
	.byt 13
	.byte "\x1d\x01\x0c\x1d\xa0\x01\x0b W"
	.byt 13
	.byte "\x1d\x01\x0c\x1d \x01\x0bV \x03"
hurtxt	.byte "\x13\x96\x01\x09\x11\x01\x0c congratulations!"
	.byt 13
	.byte "\x11\x01\x08 \x1fyour score qualifies you"
	.byt 13
	.byte "\x11\x01\x0b for \x1e\xb7\xba\xbb \xb7\xb8\xb9 \xbc\xb8\xb8\x1f !!"
	.byt 13
	.byte "\x11\x01\x0a you're new number \x81\x03"
hur2	.byt 13
	.byte "\x1f\x11 please enter your name:\x81 \x03"
statx	.byte "\x13\x11\x9cwhich stage ? (a-z)\x03"
levlx	.byte "\x13\x11\x9cwhich level ? (0-9)\x03"
inltx	.byte "\x13\x01\x11\x11\x01\x0a \x9achoose skill level !"
	.byt 13
	.byte "\x11\x11\x97 whoo\xb9\xbb\xbb!   snappy   premium   unleaded"
	.byt 13
	.byte "\x01\x05 \x11\x11\x9ause joystick or <\x9ee\x9a> for \x9eeditor\x03"
ballx	=251
bally	=253
bpf	=$2ae
seeball	=6
plx	=181
ply	=182
ojoy	=$2a7
joyc	.byt 1
odir	=143
add	=$2b1
back	=170
seed	=$2a9
spmem	=$2aa
score	=166
rech	=784
zahl	=$2b2
odirk	=$2ab
char	=$2b3
irq2ctr	.byt 1
posball	=$2af
hiadd	=$2a8
vflag	=$2b6
sel	=$2b7
art	=$2b9
stanr	=171
lives	=139
level	=140
time	=36
timdel	=$2bb
pokcol	=787
pokart	=34
spctr	=$2b4
speed	=141
pokwcol	.byt 1
kollss	=142
anzpos	=$2ba
oldsc1	=786
poklr	=35
neuhi	=$2b0
lg	=$2b8
anzoi	=168
xmem	=$2ac
ymem	=$2ad
jobnr	=254
ene1	.byt 1
enespd	=37
ene2	=$2b5
ctab	.byt 114,0,110,112,0,114,111,109
	.byt 109,112,113,0,111,110,0,113
colt	.byt 10,7,2,14
zetab	.word 10000,1000,100,10,1
irqtab	.byt 64,15
irqdef	=4	; 64/15
enespdt	.byt 90,72,61,51,42,33,25,18,12,7
	.byt 5,3,2,1,3,5
ene0	=6
coltab	.byt 9,10,12,14
levelpos	.word $a000,$a320,$a640,$a960,$ac80,$afa0
	.word $b2c0,$b5e0,$b900,$bc20
colhtab	.byt 11,12,15,1,15,12,11
anzeige	brk
pokcol1	.byt 1,15,12,11,0,11,12,15
pokcol2	.byt 7,10,2,8,7,10,2,8
grbit	.byt 1,2,4,8,16,32,64,128
nobit	.byt 251,247,239,223,191,127
colet	.byt 9,11,11,12,12,10,14,14
coleh	.byt 2,2,2,14,12,9,9,9,0
colel	.byt 14,14,12,14
wint	.byt 3,3,3,3,3,7,7,7,10,10,13,13
	.byt 17,17,27,33
enecol	.byt 1,7,14,13,10,12,15,1,3,6,7
	.byt 12,4,14,5,8
vidinit	jsr cint
	lda #196
	sta scrn
	lda #0
	sta bank
	lda #24
	sta vic+24
	lda #0
	sta vic+32
	sta vic+33
	lda #160
	sta sptr
	lda #0
	tax
	tay
clrspr	sta spr,x
	sta spr+64,x
	dex
	bne clrspr
copyspr	lda kug,x
	sta spr,y
	lda kug+8,x
	sta spr+64,y
	lda kug+16,x
	sta spr+128,y
	lda kug+24,x
	sta spr+192,y
	lda kug+32,x
	sta spr+256,y
	iny
	iny
	iny
	inx
	cpx #8
	bcc copyspr
	rts
picout	lda #<pic
	ldy #>pic
strout	tax
	lda tmp
	pha
	stx tmp
	lda tmp+1
	pha
	sty tmp+1
stout	ldy #0
	lda (tmp),y
	beq fin
	cmp #"\x03"
	beq fin
	cmp #"\x17"
	beq wis
	cmp #"\x1a"
	beq colorx
	cmp #"\x01"
	beq rept
	jsr bsout
ct	inc tmp
	bne stout
	inc tmp+1
	bne stout
wis	lda #<wiese
	ldy #>wiese
	jsr strout
	jmp ct
fin	pla
	sta tmp+1
	pla
	sta tmp
	rts
rept	iny
	lda (tmp),y
	tax
	iny
	lda (tmp),y
repe	jsr bsout
	dex
	bne repe
	lda tmp
	clc
	adc #3
	sta tmp
	bcc stout
	inc tmp+1
	bne stout
colorx	jsr rnd
	and #3
	tax
	lda colt,x
	sta color
	bne ct
rnd	lda seed
	eor vic+18
	asl
	adc #0
	adc uhr
	sta seed
mec	rts
mac3	and #15
	cmp #3
	bcc mec
	sbc #3
	bpl mac3
adds0	php
	sei
	clc
	adc score
	sta score
	bcc okinc
	inc score+1
	bne okinc
	lda #-1
	sta score
	sta score+1
okinc	plp
	rts
play	lda #0
	sta score
	sta score+1
	lda #3
	sta lives
	lda #0
	sta level
	rts
playlev	sei
	lda #6
	sta ply
	lda #20
	sta plx
	inc posball
	lda #1
	sta odir
	ldx #160
	stx sptr
	ldx #ene0
	stx enespd
	ldx #0
	stx ene2
	sta anzeige
	sta seeball
	lda #<stack
	ldy #>stack
	sta ptr
	sty ptr+1
	cli
	rts
irq5	lda seeball
	beq mec
	dec timdel
	bne mec
	lda #tspd
	sta timdel
	lda time
	beq mec
	dec time
	rts
loadhs	ldx #<hiname
	ldy #>hiname
	lda #9
	jsr setnam
	lda #0
	sta sa
	lda #flo
	sta gn
	ldx #<hiadr
	ldy #>hiadr
	lda #0
	jsr load
	lda status
	and #191
	bne fillstamm
	rts
fillstamm	lda #1
	sta stanr
	ldx #0
fil1	lda stanr
	jsr calchi
	ldy #0
	tya
	sta (tmp),y
	iny
	lda #202
	sec
	sbc stanr
	sbc stanr
	sta (tmp),y
fil2	iny
	lda stamm,x
	sta (tmp),y
	inx
	cpx #5*14
	bcc oldx
	ldx #0
oldx	cpy #15
	bcc fil2
	inc stanr
	lda stanr
	cmp #101
	bcc fil1
	rts
calchi	sec
	sbc #1
	sta tmp
	lda #0
	sta tmp+1
	asl tmp
	asl tmp
	rol tmp+1
	asl tmp
	rol tmp+1
	asl tmp
	rol tmp+1
	lda tmp+1
	adc #>hiadr
	sta tmp+1
	rts
irqinit	sei
	lda #<irqn
	ldy #>irqn
	sta irqvkt
	sty irqvkt+1
	ldx #1
	stx stack-1
	dex
	stx ballx
	stx ballx+1
	stx bally
	stx plx
	stx ply
	cli
	rts
irqn	lda bild
	pha
	lda bild+1
	pha
	lda farb
	pha
	lda farb+1
	pha
	lda zahl
	pha
	ldx seeball
	lda irqtab,x
	sta irqspd
	jsr irq1
	jsr irq2
	jsr irq3
	jsr irq4
	jsr irq5
	jsr irq6
	jsr irq7
	lda vic+30
	sta kollss
	ldx #6
	pla
	sta zahl
	pla
	sta farb+1
	pla
	sta farb
	pla
	sta bild+1
	pla
	sta bild
	jmp irqold
irq1	lda #0
	sta bpf
	lda vic+1
	cmp bally
	beq ballyok
	bcc ballrauf
	dec vic+1
	inc bpf
	bne ballyok
ballrauf	inc bpf
	inc vic+1
ballyok	lda vic+16
	and #1
	cmp ballx+1
	bcc ballre
	bne ballli
	lda vic
	cmp ballx
	bcc ballre
	beq ballxok
ballli	lda vic
	bne z2540
	lda vic+16
	and #254
	sta vic+16
z2540	dec vic
	inc bpf
	bne ballxok
ballre	inc bpf
	inc vic
	bne ballxok
	inc vic+16
ballxok	lda seeball
	bne ballan
	lda #0
	sta vic+21
rettn	lda posball
	bne posen
	rts
ballan	lda vic+21
	ora #1
	sta vic+21
	lda bpf
	bne rettn
	lda plx
	bpl norx
	lda #0
norx	asl
	asl
	asl
	php
	clc
	adc #24
	sta ballx
	lda #0
	adc #0
	plp
	adc #0
	sta ballx+1
	lda ply
	asl
	asl
	asl
	adc #50
	sta bally
	lda joy
	cmp ojoy
	bne neuj
	dec joyc
	beq neuj
	rts
posen	jmp posi
neuj	lda #4
	sta joyc
	lda joy
	sta ojoy
	lda joy
	and #1
	bne nohoch
	jsr go1
nohoch	lda joy
	and #2
	bne nount
	jsr go2
nount	lda joy
	and #4
	bne norec
	jsr go3
norec	lda joy
	and #8
	bne nolink
	jsr go4
nolink	lda back
	bmi no16
	lda #0
	sta back
	lda joy
	and #16
	bne no16
	inc back
no16	rts
posi	lda ballx
	sta vic
	lda vic+16
	and #-2
	ora ballx+1
	sta vic+16
	lda bally
	sta vic+1
	dec posball
	rts
sprchg	sta spmem
	lda odir
	stx odirk
	asl
	asl
	sta add
	txa
	adc add
	tax
	lda ctab,x
	sta char
	beq wrong
	jsr cmpfur
	jsr clout
	lda (bild),y
	cmp #32
	beq ok
	cmp #118
	beq oil
	cmp #64
	beq power
wrong	sec
	rts
ok	lda vflag
	bne wrong
	lda char
	ldy #0
	sta (bild),y
	lda #1
	sta (farb),y
	ldx odirk
	stx odir
	jsr instck
	lda spmem
	cmp sptr
	bne rein
	lda #160
rein	sta sptr
	clc
	rts
clrgimm	lda #32
	sta (bild),y
	bne ok
husey	jsr instck
	lda #160
	sta sptr
	clc
	rts
power	lda #1
	sta vic+32
	jsr poweru
	dec vic+32
	jmp clrgimm
oil	lda #3
	jsr adds0
	lda anzoi
	bne einfru
	dec anzoi+1
einfru	dec anzoi
	jmp clrgimm
cmpfur	ldx odirk
	lda ply
	pha
	lda plx
	pha
	lda #0
	sta vflag
	jsr gogox
	jsr clout
	pla
	sta plx
	pla
	sta ply
	bcs bad
	lda (bild),y
	cmp #32
	beq gut
	cmp #118
	beq gut
	cmp #64
	beq gut
bad	inc vflag
gut	rts
clout	ldx ply
	cpx #25
	bcs wiwa
	jsr calcx
	lda plx
	bmi out2
	cmp #40
	bcs wiwa
	adc bild
	sta bild
	bcc out2
	inc bild+1
out2	ldy #0
	jsr farbram
	clc
wiwa	rts
poweru	sta ene2
	lda #80
	jsr adds0
	lda pokart
	beq nixaus
	ldx #0
	stx jobs
nixaus	ldx #120
wartw	jsr pauses
	dex
	bne wartw
	rts
instck	txa
	ldy #0
	sta (ptr),y
	inc ptr
	bne ie2
	inc ptr+1
ie2	rts
irq7	lda ene2
	bne irq7a
	lda #ene0
	sta enespd
	rts
irq7a	dec ene1
	bne ie2
	ldx #27
	stx ene1
	lsr
	lsr
	lsr
	lsr
	tax
	lda enespdt,x
	sta enespd
	inc ene2
	rts
irq2	lda seeball
	beq irq2b
	dec irq2ctr
	bne irq20
	lda #irqdef
	sta irq2ctr
irq2b	lda konf
	pha
	lda #53
	sta konf
	ldx #0
irq2a	lda wech,x
	asl
	adc #0
	sta wech,x
	eor #-1
	sta wech+$400,x
	inx
	cpx #8
	bcc irq2a
	pla
	sta konf
irq20	rts
go1	lda ply
	cmp #6
	bcc outk
	lda #162
	ldx #0
	jsr sprchg
	bcc gogox
	rts
go2	lda ply
	cmp #25
	bcs outk
	lda #161
	ldx #1
	jsr sprchg
	bcc gogox
	rts
go3	lda plx
	cmp #-1
	beq outk
	lda #164
	ldx #2
	jsr sprchg
	bcc gogox
	rts
go4	lda plx
	cmp #40
	bcs outk
	lda #163
	ldx #3
	jsr sprchg
	bcc gogox
	rts
gogox	txa
	beq gogo0
	dex
	beq gogo1
	dex
	beq gogo2
	inc plx
	rts
gogo2	dec plx
	rts
gogo1	inc ply
	rts
gogo0	dec ply
outk	rts
irq3	lda back
	bne irq3d
rt	rts
irq3d	lda bpf
	bne rt
	lda #160
	sta sptr
irq3a	lda ptr+1
	cmp #>stack
	bne irq3b
	lda ptr
	cmp #<stack
	bne irq3b
	lda #0
	sta back
	rts
irq3b	lda ptr
	sec
	sbc #2
	sta ptr
	lda ptr+1
	sbc #0
	sta ptr+1
irq3c	ldy #0
	lda (ptr),y
	sta odir
	inc ptr
	bne irq3e
	inc ptr+1
irq3e	lda (ptr),y
	eor #1
	tax
	jsr gogox
	jsr clout
	lda #32
	sta (bild),y
	rts
nmi4	ldx #0
	ldy #0
	lda score
	sta rech
	lda score+1
	sta rech+1
	lda sc1+1
	sta oldsc1
ri1	lda #"0"
	sta zahl
ri2	lda rech+1
	cmp zetab+1,x
	bcc ri3
	bne ri4
	lda rech
	cmp zetab,x
	bcc ri3
ri4	inc zahl
	lda rech
	sec
	sbc zetab,x
	sta rech
	lda rech+1
	sbc zetab+1,x
	sta rech+1
	jmp ri2
ri3	inx
	inx
	iny
	lda zahl
	sta sc1,y
	lda #7
	sta fa1,y
	cpy #5
	bcc ri1
	lda oldsc1
	cmp #"0"
	bcc nomercy
	cmp sc1+1
	bcs nomercy
	inc lives
nomercy	rts
irq4	lda anzeige
	bne irq4a
	rts
irq4a	ldx lives
	ldy #0
outli	txa
	beq lnil
	dex
	lda #125
	.byt $2c
lnil	lda #32
	sta sc3,y
	lda #3
	sta fa3,y
	iny
	cpy #10
	bcc outli
	lda #"0"
	sta zahl
	sta sc4+2
	lda time
	lsr
outtime	cmp #10
	bcc kl10
	sbc #10
	inc zahl
	bne outtime
kl10	ldx zahl
	stx sc4
	ora #48
	sta sc4+1
	lda #5
	sta fa4
	sta fa4+1
	sta fa4+2
	rts
loslauf	lda #111
	sta sysctl
	lda #0
	sta ioflag
	jsr loadhs
	jsr vidinit
	jsr irqinit
titel	lda #0
	sta seeball
	sta anzeige
	lda #<title
	ldy #>title
	jsr strout
stufe1	jsr clrunt
	lda #<step1
	ldy #>step1
	jsr strout
	jsr wartp
	bcc stufe2
	jmp russ
stufe2	jsr clrunt
	lda #<step2
	ldy #>step2
	jsr strout
	lda #1
	sta stanr
	jsr colinh
highsh	lda #24
	sta zei
	lda #5
	sta spa
	jsr cursor
	lda #0
	sta color
	ldx stanr
	lda #0
	jsr axout
	lda #"."
	jsr bsout
	lda #12
	sta spa
	lda stanr
	jsr calchi
	ldy #2
namout	lda (tmp),y
	jsr bsout
	iny
	cpy #16
	bcc namout
	ldx #4
spacout	jsr space
	dex
	bne spacout
	ldy #1
	lda (tmp),y
	tax
	dey
	lda (tmp),y
	jsr axout
	jsr paus
	bcs russ
	jsr scroll
	jsr paus
	bcs russ
	jsr scroll
	inc stanr
	lda stanr
	cmp #101
	bcc highsh
	lda #6
	sta stanr
scrre	jsr scroll
	jsr paus
	bcs russ
	dec stanr
	bne scrre
	beq stufe3
qedit	jsr editor
	jmp titel
russ	jsr inlevel
	bmi qedit
	cmp #"\x03"
	beq qtitel
	jsr gameon
qtitel	jmp titel
stufe3	jmp stufe1
inlevel	jsr clrunt
	lda #<inltx
	ldy #>inltx
	jsr strout
	lda #2
	sta speed
	lda #0
	sta key
bekant	lda #11
	ldx #39
defdwn	sta downline,x
	dex
	bpl defdwn
	lda speed
	asl
	asl
	adc speed
	asl
	tay
	ldx #0
	lda #7
neudwn	sta downline,y
	iny
	inx
	cpx #10
	bcc neudwn
spdjoy	jsr get
	cmp #"\x03"
	beq retbas
	cmp #"e"
	bne qspdjoy
	lda #-1
	rts
qspdjoy	jsr pausem
	lda joy
	and #16
	beq chosen
	lda joy
	and #4
	bne nos4
	lda speed
	beq spdjoy
	dec speed
	bpl bekant
nos4	lda joy
	and #8
	bne spdjoy
	lda speed
	cmp #3
	bcs spdjoy
	inc speed
	bne bekant
chosen	lda speed
	asl
	asl
	asl
	sta speed
	rts
pausem	ldx #0
pausem2	jsr pauses
	dex
	bne pausem2
retbas	rts
paus	lda stanr
	lsr
	sec
	sbc #85
	eor #-1
	tax
	ldy #0
pse	lda joy
	and #16
	beq raush
	dey
	bne pse
	dex
	bne pse
	clc
	rts
clrunt	ldx #15
cunt	jsr clrx
	inx
	cpx #25
	bcc cunt
	rts
scroll	ldx #17
	jsr calcx
scr	lda bild
	clc
	adc #40
	sta tmp
	lda bild+1
	adc #0
	sta tmp+1
	ldy #35
scl	lda (tmp),y
	sta (bild),y
	dey
	bne scl
	lda tmp
	sta bild
	lda tmp+1
	sta bild+1
	inx
	cpx #24
	bcc scr
	jmp clrx
colinh	ldx #17
clinh	jsr calcx
	jsr farbram
	ldy #35
	lda colhtab-17,x
clinn	sta (farb),y
	dey
	bne clinn
	inx
	cpx #25
	bcc clinh
	rts
wartp	ldx #0
	ldy #10
	sty stanr
wtp	lda joy
	and #16
	beq raush
	dex
	bne wtp
	dey
	bne wtp
	dec stanr
	bne wtp
	clc
	rts
raush	sec
	rts
gameon	jsr play
	jmp runde
tune	jsr picout
	lda #<tunt
	ldy #>tunt
	jsr strout
	lda level
	asl
	asl
	asl
	adc #<ziff
	sta tmp
	lda #>ziff
	adc #0
	sta tmp+1
	ldy #0
zifzei	tya
	pha
	lda #<posix
	ldy #>posix
	jsr strout
	pla
	tay
	ldx #7
zifspa	lda #53
	sei
	sta konf
	lda (tmp),y
	inc konf
	inc konf
	cli
	and grbit,x
	beq bit0
	lda #221
	.byt $2c
bit0	lda #32
	jsr bsout
	dex
	bpl zifspa
	iny
	cpy #8
	bcc zifzei
	sei
	lda #4
	ldy #80
	ldx #0
watu	dex
	bne watu
	dey
	bne watu
	sec
	sbc #1
	bne watu
	cli
	rts
runde	jsr clrjob
	jsr tune
	lda level
	jsr calcl
	jsr hollev
	jsr playlev
inloop	lda #99
	sta time
	lda #tspd
	sta timdel
mainloop	jsr nmi4
	lda anzoi
	bne zutun
	lda anzoi+1
	bne zutun
	jmp hurra
zutun	jsr stop
	lda kollss
	and #1
	beq nixss
	lda kollss
	and #2
	beq nix2
	lda jobs
	beq nix2
	lda vic+3
	jsr testy
	beq nix2
	lda pokart
	beq kohle
	jmp faul
kohle	jsr off2
	lda #250
	jsr adds0
nix2	ldx #0
nixlp	lda kollss
	and grbit+2,x
	beq nixslp
	lda jobs+1,x
	beq nixslp
	txa
	asl
	tay
	lda vic+5,y
	jsr testy
	beq nixslp
	lda #0
	sta jobs+1,x
	lda sptr+2,x
	sec
	sbc #167
	tay
	lda wint,y
	ldy #0
	jsr adds0
nixslp	inx
	cpx #6
	bcc nixlp
nixss	lda time
	beq faul
	ldx #0
testsh	stx tmp
	lda jobs+1,x
	beq spriaus
	txa
	asl
	tay
	lda vic+5,y
	sec
	sbc #zei1-47
	lsr
	lsr
	lsr
	tax
	jsr calcx
	ldx tmp
	lda vic+16
	and grbit+2,x
	beq sonul
	lda #1
sonul	sta tmp+1
	lda vic+4,y
	sec
	sbc #16
	pha
	lda tmp+1
	sbc #0
	lsr
	pla
	ror
	lsr
	lsr
	tay
	cpy #40
	bcs spriaus
	lda (bild),y
	cmp #109
	bcc spriaus
	cmp #115
	bcc faul
spriaus	ldx tmp
	inx
	cpx #6
	bcc testsh
	jmp mainloop
faul	jmp tod
off2	lda #0
	sta jobs
	lda vic+21
	and #253
	sta vic+21
	rts
testy	sbc vic+1
	bcs positic
	eor #-1
positic	cmp #8
	bcc outside
	lda #0
outside	rts
tod	jsr off2
	jsr blinken
	lda #-1
	sta back
wb	cmp back
	beq wb
	dec lives
	beq gover
	jmp inloop
gover	jsr clrjob
	lda #<gomt
	ldy #>gomt
	jsr strout
dag	lda #16
	and joy
	beq dag
d	lda #16
	and joy
	bne d
	lda #100
	sta stanr
inhig	lda stanr
	jsr calchi
	ldy #0
	lda (tmp),y
	cmp score+1
	bcc kleis
	bne gross
	iny
	lda (tmp),y
	cmp score
	bcs gross
kleis	dec stanr
	bne inhig
gross	inc stanr
	lda stanr
	cmp #101
	bcc klappt
	rts
klappt	jsr picout
	lda #<hurtxt
	ldy #>hurtxt
	jsr strout
	ldx stanr
	lda #0
	jsr axout
	lda #<hur2
	ldy #>hur2
	jsr strout
	ldy #0
namin	lda #0
	sta crs1
	sty lg
wank	jsr get
	beq wank
	ldy lg
	cmp #20
	beq erl
	cmp #13
	beq erl
	cmp #32
	bcc wank
	cmp #128
	bcs wank
	cpy #14
	bcs wank
erl	ldx #1
	stx crs2
wc0	ldx crs3
	bne wc0
	inc crs1
	cmp #13
	beq finin
	cmp #20
	bne ascii
	tya
	beq namin
	dey
	lda #20
	jsr bsout
	bcc namin
ascii	jsr bsout
	sta hipname,y
	iny
	bne namin
finin	cpy #14
	bcs fullh
	lda #32
	sta hipname,y
	iny
	bne finin
fullh	ldx stanr
	stx neuhi
	lda #100
	sta stanr
copydwn	lda stanr
	cmp neuhi
	beq ut
	jsr calchi
	lda tmp
	sec
	sbc #16
	sta tmp2
	lda tmp+1
	sbc #0
	sta tmp2+1
	ldy #15
copyd1	lda (tmp2),y
	sta (tmp),y
	dey
	bpl copyd1
	dec stanr
	jmp copydwn
ut	lda neuhi
	jsr calchi
	ldy #0
	lda score+1
	sta (tmp),y
	iny
	lda score
	sta (tmp),y
	iny
	ldx #0
rinna	lda hipname,x
	sta (tmp),y
	iny
	inx
	cpx #14
	bcc rinna
	jsr clall
	lda #15
	ldx #flo
	tay
	jsr setpar
	ldx #<hiscr
	ldy #>hiscr
	lda #11
	jsr setnam
	jsr open
	lda #15
	jsr close
	ldx #<hiname
	ldy #>hiname
	lda #9
	jsr setnam
	ldx #flo
	ldy #1
	jsr setpar
	ldx #<hiende
	ldy #>hiende
	lda #<hiadr
	sta tmp
	lda #>hiadr
	sta tmp+1
	lda #tmp
	jmp save
hurra	ldx #10
	sei
hor	lda time
	lsr
	jsr adds0
	dex
	bne hor
	cli
	jsr nmi4
	inc level
	lda level
	cmp #10
	bcc weiter
	lda #0
	sta level
	lda speed
	cmp #8
	bcc weiter
	sbc #8
	sta speed
weiter	jmp runde
stop	jsr get
	cmp #"\x03"
	beq halt
	rts
halt	sei
	ldx #4
sttaus	lda paut,x
	sta sc4-1,x
	lda #10
	sta fa4-1,x
	dex
	bpl sttaus
gcont	lda joy
	and #16
	bne ni16
	lda #32
	sta sc4-1
	sta sc4+3
	cli
	rts
ni16	lda joy
	and #1
	bne gcont
	lda #32
	sta sc4-1
	sta sc4+3
	cli
	pla
	pla
	jmp gover
blinky	tax
	lda #<anfscr
	ldy #>anfscr
	sta tmp
	sty tmp+1
	lda #<stack-1
	ldy #>stack-1
	sta tmp2
	sty tmp2+1
	ldy #0
bky	lda tmp2
	cmp ptr
	bne furb
	lda tmp2+1
	cmp ptr+1
	beq doneb
furb	txa
	sta (tmp),y
	lda (tmp2),y
	beq bb1
	cmp #1
	beq bb2
	cmp #2
	beq bb3
	inc tmp
	bne lauf
	inc tmp+1
	bne lauf
bb3	lda tmp
	bne bb3a
	dec tmp+1
bb3a	dec tmp
	jmp lauf
bb1	lda tmp
	sec
	sbc #40
	sta tmp
	lda tmp+1
	sbc #0
	sta tmp+1
	jmp lauf
bb2	lda tmp
	clc
	adc #40
	sta tmp
	bcc lauf
	inc tmp+1
lauf	inc tmp2
	bne bky
	inc tmp2+1
	bne bky
blinken	sei
	lda #9
	sta tmp3
blilo	lda #2
	jsr blinky
	jsr delayb
	lda #1
	jsr blinky
	jsr delayb
	dec tmp3
	bne blilo
	cli
	rts
delayb	ldx #0
	ldy #60
dkly	dex
	bne dkly
	dey
	bne dkly
doneb	rts
editor	jsr picout
home	lda #6
	sta zei
	lda #0
	sta spa
neu	jsr cursor
	jsr farbram
mai	ldx #0
	stx key
	stx crs1
	stx vic+32
	inx
	stx color
ge	jsr get
	beq ge
	ldx #1
	stx crs2
gc	ldx crs3
	bne gc
	inc crs1
	cmp #"\x13"
	beq home
	cmp #"\x11"
	bne no1
dn	lda zei
	cmp #24
	bcs mai
	inc zei
	bne neu
no1	cmp #"\x91"
	bne no2
	lda zei
	cmp #7
	bcc mai
	dec zei
	bne neu
no2	cmp #"\x1d"
	bne no3
le	lda spa
	cmp #39
	bcs mai
	inc spa
	bne neu
no3	cmp #"\x9d"
	bne no4
	lda spa
	beq mai
	dec spa
	bpl neu
no4	cmp #13
	bne no5
	lda #0
	sta spa
	beq dn
no5	cmp #"\x93"
	bne no6
clr	lda #39
	sta spa
	lda #24
	sta zei
	bne neu
no6	cmp #"1"
	bcc no7
	cmp #"5"
	bcs no7
	sbc #"0"
	tax
	ldy spa
	lda coltab,x
	sta (farb),y
	stx hiadd
	txa
	asl
	adc #65
	adc hiadd
	sta hiadd
	jsr rnd
	jsr mac3
	clc
	adc hiadd
	sta (bild),y
	bne le
no7	cmp #"!"
	bcc no8
	cmp #"%"
	bcs no8
	sbc #32
	tax
	lda coltab,x
	sta smod+1
	stx hiadd
	txa
	asl
	adc hiadd
	adc #65
	sta hiadd
loop1	jsr cursor
	jsr farbram
	ldy spa
loop2	jsr rnd
	jsr mac3
	clc
	adc hiadd
	sta (bild),y
smod	lda #0
	sta (farb),y
	iny
	cpy #40
	bcc loop2
	inc zei
	lda zei
	cmp #25
	bcc loop1
	jmp clr
no8	cmp #32
	bne no9
set	ldy spa
	sta (bild),y
	txa
	sta (farb),y
	jmp le
no9	cmp #"5"
	bne no10
	lda #118
	ldx #7
	bne set
no10	cmp #"6"
	bne no11
	lda #64
	ldx #13
	bne set
no11	cmp #"\x03"
	bne no12
	rts
no12	cmp #"l"
	bne no13
loads	jsr getnr
	bcs qhome
	jsr hollev
qhome	jmp home
no13	cmp #"s"
	bne no14
	jsr getnr
	bcs qhome
	lda #<sc2
	ldy #>sc2
	sta tmp2
	sty tmp2+1
	ldy #0
copys	lda (tmp2),y
	sta (tmp),y
	inc tmp
	bne nos1
	inc tmp+1
nos1	inc tmp2
	bne nos2
	inc tmp2+1
nos2	lda tmp2
	cmp #<endscr
	bne copys
	lda tmp2+1
	cmp #>endscr
	bne copys
	ldy #18
savact	lda aktiv,y
	sta (tmp),y
	dey
	bpl savact
	jmp home
no14	cmp #"t"
	bne no15
	jsr playlev
gtt	jsr get
	cmp #"\x03"
	bne gtt
	jsr callb
	lda #0
	sta seeball
	jmp mai
no15	cmp #"g"
	beq ghostpgm
	jmp ne16
ghostpgm	lda irqvkt
	pha
	lda irqvkt+1
	pha
	sei
	lda #<rirq
	ldy #>rirq
	sta irqvkt
	sty irqvkt+1
	lda #zei1
	sta vic+18
	lda vic+17
	and #127
	sta vic+17
	lda #129
	sta vic+26
	cli
	jsr positg
	sei
	lda #0
	sta vic+26
	pla
	sta irqvkt+1
	pla
	sta irqvkt
	cli
	jmp mai
getnr	lda #<levlx
	ldy #>levlx
	jsr strout
	lda #5
	sta vic+32
gnr	jsr get
	cmp #"\x03"
	bne weit
rausnr	jsr clrto
	sec
	rts
weit	cmp #"0"
	bcc gnr
	cmp #"9"+1
	bcs gnr
	sbc #"0"-1
	pha
	jsr clrto
	pla
calcl	asl
	tax
	lda levelpos,x
	sta tmp
	lda levelpos+1,x
	sta tmp+1
	clc
	rts
hollev	lda #<sc2
	ldy #>sc2
	sta tmp2
	sty tmp2+1
	lda #<fa2
	ldy #>fa2
	sta tmp3
	sty tmp3+1
	ldy #0
	sei
	lda #54
	sta konf
	sty anzoi
	sty anzoi+1
copyl	lda (tmp),y
	sta (tmp2),y
	cmp #118
	bne heiwei
	inc anzoi
	bne heiwei
	inc anzoi+1
heiwei	cmp #65
	bcc nosp
	ldx #0
	cmp #68
	bcc sete
	inx
	cmp #71
	bcc sete
	inx
	cmp #74
	bcc sete
	inx
	cmp #77
	bcs nosp
sete	lda coltab,x
	bne setit
nosp	jsr efab
setit	sta (tmp3),y
	inc tmp3
	bne noi3
	inc tmp3+1
noi3	inc tmp2
	bne noi2
	inc tmp2+1
noi2	inc tmp
	bne noi1
	inc tmp+1
noi1	lda tmp2
	cmp #<endscr
	bne copyl
	lda tmp2+1
	cmp #>endscr
	bcc copyl
	ldy #18
	lda #32
	sta secber
holact	lda (tmp),y
	sta aktiv,y
	dey
	bpl holact
	lda #55
	sta konf
	cli
	rts
callb	lda #-1
	sta back
cbk	cmp back
	beq cbk
	rts
clrto	pha
	ldx #18
	lda #32
pen0	sta sc3+40,x
	dex
	bpl pen0
	pla
	rts
rirq	lda vic+25
	sta vic+25
	lsr
	bcs rok
	lda irql
	cli
	jmp irqold
rok	lda vic+18
	pha
	sec
	sbc #zei1
	lsr
	lsr
	lsr
	tax
	pla
	clc
	adc #8
	cpx #19
	bcc reinr
	lda #zei1
	ldx #-1
reinr	sta vic+18
	cpx sel
	beq red
aso	txa
	bmi swf
	lda aktiv,x
	jmp rine
swf	lda art
	eor #1
	sta art
	lda #0
	.byt $2c
red1	lda #10
rine	sta vic+32
	jmp irqoff
red	lda art
	beq red1
	bne aso
positg	jsr get
	cmp #"\x03"
	bne noc
	rts
noc	cmp #"\x11"
	bne nodwn
	lda sel
	cmp #18
	bcs positg
	inc sel
	bne positg
nodwn	cmp #"\x91"
	bne nogup
	lda sel
	beq positg
	dec sel
	bpl positg
nogup	cmp #13
	bne noset
	ldx sel
	lda aktiv,x
	eor #1
	and #1
	sta aktiv,x
	bpl positg
noset	cmp #"\x93"
	bne positg
	ldx #18
invall	lda #0
	sta aktiv,x
	dex
	bpl invall
	bmi positg
irq6	ldx #0
	lda seeball
	bne angg
rueck	rts
angg	dec spctr
	bne rueck
	lda enespd
	clc
	adc speed
	sta spctr
ang	lda jobs,x
	stx jobnr
	cpx #1
	bcc zwei
	jmp others
zwei	tax
	beq pokaus
	lda vic+21
	ora #2
	sta vic+21
	lda poklr
	bne rec
	inc vic+2
	bne noi16
	lda vic+16
	ora #2
	sta vic+16
noi16	lda vic+16
	and #2
	beq gopok
	lda vic+2
	cmp #90
	bcc gopok
pokstop	lda #0
	sta jobs
	jmp jobloop
rec	lda vic+2
	bne nod16
	lda vic+16
	and #253
	sta vic+16
nod16	dec vic+2
	lda vic+16
	and #2
	bne gopok
	lda vic+2
	beq pokstop
gopok	ldx pokcol
	lda pokart
	beq pokal
	lda pokcol2,x
	bne setpokcol
pokal	lda pokcol1,x
setpokcol	sta vic+40
	inc pokcol
	cpx #7
	bcc qjob
	lda #0
	sta pokcol
qjob	jmp jobloop
pokaus	lda vic+21
	and #253
	sta vic+21
	jsr rnd
	cmp #60
	bcs qjob
	jsr rnd
	cmp #10
	bcc mapok
	cmp #25
	bcs qjob
	lda #1
	.byt $2c
mapok	lda #0
	sta pokart
	clc
	adc #165
	sta sptr+1
	jsr wurfy
	beq qjob
	sta vic+3
	lda #0
	sta poklr
	inc jobs
	jsr rnd
	cmp #128
	bcc re
	lda vic+16
	and #253
	sta vic+16
	lda #0
	sta vic+2
	beq qjob
re	inc poklr
	lda vic+16
	ora #2
	sta vic+16
	lda #90
	sta vic+2
	bne qjob
others	pha
	ldx jobnr
	dex
	txa
	asl
	tay
	pla
	cmp #0
	beq eneaus
	lda vic+21
	ora grbit+2,x
	sta vic+21
	lda richt,x
	bne erec
	lda vic+4,y
	clc
	adc #1
	sta vic+4,y
	bne noi16e
	lda vic+16
	ora grbit+2,x
	sta vic+16
noi16e	lda vic+16
	and grbit+2,x
	beq goene
	lda vic+4,y
	cmp #90
	bcc goene
enestop	lda #0
	sta jobs+1,x
	jmp jobloop
erec	lda vic+4,y
	bne nod16e
	lda vic+16
	and nobit,x
	sta vic+16
nod16e	lda vic+4,y
	sec
	sbc #1
	sta vic+4,y
	lda vic+16
	and grbit+2,x
	bne goene
	lda vic+4,y
	beq enestop
goene	jmp jobloop
eneaus	lda vic+21
	and nobit,x
	sta vic+21
	jsr rnd
	cmp #4
	bcs jobloop
	jsr rnd
	cmp #80
	bcs jobloop
	jsr rnd
	and #15
	pha
	stx bild
	tax
	lda enecol,x
	ldx bild
	sta vic+41,x
	pla
	clc
	adc #167
	sta sptr+2,x
	jsr wurfy
	beq jobloop
	sta vic+5,y
	lda #0
	sta richt,x
	inc jobs+1,x
	jsr rnd
	cmp #128
	bcc enere
	lda vic+16
	and nobit,x
	sta vic+16
	lda #0
	sta vic+4,y
	beq jobloop
enere	inc richt,x
	lda vic+16
	ora grbit+2,x
	sta vic+16
	lda #90
	sta vic+4,y
jobloop	ldx jobnr
	inx
	cpx #7
	bcs freiz
	jmp ang
freiz	rts
qwurfy	ldx #18
	lda #0
	tay
wu1	lda aktiv,x
	beq keins
	txa
	sta possi,y
	iny
keins	dex
	bpl wu1
	tya
	bne drin
	rts
drin	sty anzpos
	jsr rnd
ma18	cmp anzpos
	bcc gu18
	sbc anzpos
	bne ma18
gu18	tax
	lda possi,x
	asl
	asl
	asl
	adc #zei1+1
	rts
wurfy	stx xmem
	sty ymem
	jsr qwurfy
	php
	ldx xmem
	ldy ymem
	plp
	rts
getsnr	lda #<statx
	ldy #>statx
	jsr strout
	lda #2
	sta vic+32
gsnr	jsr get
	cmp #"\x03"
	bne weeit
	jmp rausnr
weeit	cmp #"a"
	bcc gsnr
	cmp #"z"+1
	bcs gsnr
	sta stname+10
	jsr clrto
	clc
	rts
efab	cmp #118
	beq j118
	cmp #64
	beq j64
	cmp #127
	beq ja127
	cmp #86
	beq j86
	cmp #233
	bcc kl233
	cmp #237
	bcc kl237
kl233	cmp #247
	bcc kl247
	sbc #247
	tax
	lda coleh,x
	rts
kl247	sec
	sbc #97
	cmp #8
	bcc kl978
	lda #0
	rts
kl978	tax
	lda colet,x
	rts
j118	lda #7
	rts
j64	lda #13
	rts
ja127	lda #12
	rts
j86	lda #9
	rts
kl237	sbc #232
	tax
	lda colel,x
	rts
clrjob	ldx #6
	lda #0
	sta seeball
clrjj	sta jobs,x
	dex
	bpl clrjj
	rts
ne16	cmp #"7"
	bne no17
	lda #97
	ldx #9
setu	ldy spa
	sta (bild),y
	txa
	sta (farb),y
	jmp le
no17	cmp #"8"
	bne no18
	lda #127
	ldx #12
	bne setu
no18	cmp #"9"
	bne no19
	lda spa
	cmp #39
	bcc okh
noh	jmp mai
okh	lda zei
	cmp #24
	bcs noh
	ldy spa
	lda #98
	sta (bild),y
	lda #11
	sta (farb),y
	iny
	sta (farb),y
	lda #99
	sta (bild),y
	tya
	clc
	adc #40
	tay
	lda #12
	sta (farb),y
	dey
	sta (farb),y
	lda #100
	sta (bild),y
	iny
	lda #101
	sta (bild),y
	inc spa
	jmp le
no19	cmp #"z"
	bne no20
	lda #103
drx	ldx #14
	bne setu
no20	cmp #"x"
	bne no21
	lda #104
	bne drx
no21	cmp #"0"
	bne no22
	lda #102
	ldx #10
	bne setu
no22	cmp #"L"
	bne no23
	jsr getsnr
	bcc okl
qqhome	jmp home
okl	ldx #<stname
	ldy #>stname
	lda #11
	jsr setnam
	lda #0
	sta sa
	lda #flo
	sta gn
	ldx #<levelmem
	ldy #>levelmem
	lda #0
	jsr load
	jmp loads
no23	cmp #"S"
	bne no24
	jsr getsnr
	bcs qqhome
	jsr clall
	lda #15
	ldx #flo
	tay
	jsr setpar
	ldx #<stscr
	ldy #>stscr
	lda #13
	jsr setnam
	jsr open
	lda #15
	jsr close
	ldx #<stname
	ldy #>stname
	lda #11
	jsr setnam
	ldx #flo
	ldy #1
	jsr setpar
	ldx #<levelend
	ldy #>levelend
	lda #54
	sta konf
	lda #<levelmem
	sta tmp
	lda #>levelmem
	sta tmp+1
	lda #tmp
	jsr save
	inc konf
	jmp home
no24	cmp #"d"
	bne no25
	lda #252
no24a	ldx #9
quset	jmp setu
no25	cmp #"\"
	bne no26
	lda #86
	bne no24a
no26	cmp #"+"
	bne no27
	lda #253
	bne no24a
no27	cmp #"-"
	bne no28
	lda #254
	bne no24a
no28	cmp #"r"
	bne no29
	lda spa
	cmp #39
	bcs qqmai
	ldy spa
	lda #233
	sta (bild),y
	lda #14
	sta (farb),y
	iny
	sta (farb),y
	lda #234
	sta (bild),y
	inc spa
	jmp le
no29	cmp #"e"
	bne no30
	lda #235
no29a	ldx #12
	bne quset
no30	cmp #"h"
	bne no31
	lda #236
no30a	ldx #14
	bne quset
no31	cmp #","
	bne no32
	lda #247
no31a	ldx #2
	bne quset
no32	cmp #"."
	bne no33
	lda #248
	bne no31a
qqmai	jmp mai
no33	cmp #"/"
	bne no34
	lda #249
	bne no31a
no34	cmp #"v"
	bne no35
	lda #250
	bne no30a
no35	cmp #"i"
	bne qqmai
	lda #251
	bne no29a